@create +staff Device=10
&MONTH_DATA +staff Device=Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec
&FN_MAKE_DATE +staff Device=[elements(%0,4)] - [member(v(month_data),elements(%0,2))]/[elements(%0,3)]/[elements(%0,5)]
&FN_FORMAT_SECS +staff Device=[setq(0,div(%0,86400))][ifelse(gt(%q0,0),%q0d%b,)][u(fn_digit_format,div([ifelse(gt(%q0,0),mod(%0,86400),%0)],3600))]:[u(fn_digit_format,div(mod(%0,3600),60))]:[u(fn_digit_format,mod(%0,60))]
&FN_DIGIT_FORMAT +staff Device=[switch(lte(%0,9),1,0)]%0
&PSTAFF +staff Device=$staff:think u(fn_list_staff,wizlist,wposition,*,c,[mudname()] WIZZES,hy)
&FN_FORMAT_ENTRY +staff Device=[setq(0,name(%0))][setq(1,u(%0/%1))]%q0[space(sub(10,strlen(%q0)))][strtrunc(%q1,39)][space(sub(39,strlen(%q1)))][ifelse(hasflag(%0,connected),Idle: [u(fn_format_secs,idle(%0))],u(fn_make_date,get(%0/last)))]
&FN_LIST_STAFF +staff Device=[pemit(%#,center(ansi(%5,~ %4 ~),77))][pemit(%#,ansi(h,NAME[repeat(%b,6)]POSITION[repeat(%b,28)]LAST ON))][pemit(%#,ansi(%3,repeat(%2,div(77,strlen(%2)))))][pemit(%#,list(v(%0),u(fn_format_entry,##,%1)))][pemit(%#,ansi(%3,repeat(%2,div(77,strlen(%2)))))]
@set +staff Device=INHERIT
@set +staff Device=SAFE

@create Time Functions=10
&FN_TIME Time Functions=[elements(%0,4)]
&FN_MONTH Time Functions=[elements(%0,2)]
&FN_DATE Time Functions=[elements(%0,3)]
&FN_YEAR Time Functions=[elements(%0,5)]
&MONTH_DATA Time Functions=Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec
&FN_NUM_MONTH Time Functions=[member(v(month_data),u(fn_month,%0))]
&FN_MAKE_DATE Time Functions=[u(fn_time,%0)] - [u(fn_num_month,%0)]/[u(fn_date,%0)]/[u(fn_year,%0)]
&FN_FORMAT_SECS Time Functions=[setq(0,div(%0,86400))][ifelse(gt(%q0,0),%q0d%b,)][u(fn_digit_format,div([ifelse(gt(%q0,0),mod(%0,86400),%0)],3600))]:[u(fn_digit_format,div(mod(%0,3600),60))]:[u(fn_digit_format,mod(%0,60))]
&FN_DIGIT_FORMAT Time Functions=[switch(lte(%0,9),1,0)]%0
&FN_LONG_TIME_FORMAT Time Functions=[setq(0,div(%0,86400))][ifelse(gt(%q0,0),%q0d%b,)][div([ifelse(gt(%q0,0),mod(%0,86400),%0)],3600)]h [div(mod(%0,3600),60)]m [mod(%0,60)]s
&FN_FORMAT_ONFOR Time Functions=[ifelse(gte(%0,31449600),[div(%0,31449600)]y,ifelse(gte(%0,604800),[div(%0,604800)]w,ifelse(gte(%0,86400),[div(%0,86400)]d,ifelse(gte(%0,3600),[div(%0,3600)]h,ifelse(gte(%0,60),[div(%0,60)]m,%0s)))))]

@create Admin Globals=10
@lock Admin Globals=*Yohshee
&IS_ADMIN Admin Globals=[orflags(%#,WZ)]
@lock/UseLock Admin Globals=IS_ADMIN/1
&PSUSPECT Admin Globals=$+suspect *:@switch hastype(*%0,player)=1,{@switch orflags(*%0,!W!Z!?)=1,{@set *%0=suspect; @pemit %#=Set.},{@pemit %#=You are not allowed to do that.}},{@pemit %#=That isn't an existing player.}
&PUNSUSPECT Admin Globals=$+unsuspect *:@switch hastype(*%0,player)=1,{@switch orflags(*%0,!W!Z!?)=1,{@set *%0=!suspect; @pemit %#=Cleared.},{@pemit %#=You are not allowed to do that.}},{@pemit %#=That isn't an existing player.}
&PUNINSPECT Admin Globals=$+uninspect:@switch hastype(loc(%#),room)=1,{@set [loc(%#)]=uninspected; @pemit %#=Set.},{@pemit %#=You must be in a room to do this.}
&IDLEROOM Admin Globals=<idle room dbref>
&PIDLEOUT Admin Globals=$+idleout *:@switch hastype(*%0,player)=1,{@switch orflags(*%0,!W!Z!?)=1,{@teleport/quiet *%0=[u(idleroom)]; @pemit %#=[name(*%0)] has been sent to the [name(u(idleroom))].},{@pemit %#=You aren't allowed to do that.}},{@pemit %#=That isn't an existing player.}
@set Admin Globals=INHERIT
@set Admin Globals=SAFE

@create Teleport Device=10
@lock Teleport Device=*Yohshee
&PSUMMON Teleport Device=$+summon *:@switch hasflag(%#,W)=1,{@switch hastype(*%0,player)=1,{@remit loc(*%0)=[ansi(hc,[name(*%0)] has been summoned by the staff and will be teleported in 3 seconds.)]; @wait 3={@teleport *%0=loc(%#)}},{@pemit %#=That is not an existing player on [mudname()].}},{@pemit %#=You are not allowed to do that.}
&PJOIN Teleport Device=$+join *:@switch hasflag(%#,W)=1,{@switch hastype(*%0,player)=1,{@remit loc(*%0)=[ansi(hc,You will be joined by %n in 3 seconds.)]; @wait 3={@teleport %#=loc(*%0)}},{@pemit %#=That isn't an existing player on [mudname()].}},{@pemit %#=You are not allowed to do that.}
&PTELEPORT Teleport Device=$+teleport:think [ifelse(gt(words(v(locations)),0),pemit(%#,ansi(h,Public Locations:))][pemit(%#,list(v(locations),[name(##)] - ##)),pemit(%#,ansi(h,No public locations have been saved.)))]
&PADDLOC Teleport Device=$+teleport/add *:@switch isdbref(%0)=1,{&locations me=[v(locations)] %0; @pemit %#=[name(%0)] has been added to the list.},{@pemit %#=That is not a valid dbref.}
&PREMOVELOC Teleport Device=$+teleport/remove *:@switch isdbref(%0)=1,{&locations me=[ldelete(v(locations),member(v(locations),%0))]; @pemit %#=[name(%0)] has been removed from the list.},{@pemit %#=That is not a valid dbref.}
@set Teleport Device=INHERIT
@set Teleport Device=SAFE

@create +finger Device=10
@lock +finger Device=*Yohshee
&PFINGER +finger Device=$+finger *:think [ifelse(strmatch(%0,me),setq(0,%#),setq(0,num(*%0)))][switch(isdbref(%q0),1,pemit(%#,[center(ansi([v(head_color)],[mudname()] +Finger for [name(%q0)][ifelse(v(showflags),\([num(%q0)][flags(%q0)]\),)]),80)]%r[repeat(ansi([v(border_color)],-=),40)]%r[ifelse(hasflag(%q0,connected),[center([ansi(v(head_color),name(%q0))] has been on for [u(fn_time_format,%q0)],80)],[center([ansi(v(head_color),name(%q0))] was last on at [get(%q0/last)],80)])]%r[repeat(ansi([v(border_color)],-=),40)]%r[ifelse(gt(elements(mail(name(%q0)),2),0),ansi(v(head_color),MAIL: [elements(mail(name(%q0)),2)] unread messages.),ansi(v(head_color),MAIL: No unread mail.))]%r[iter(u(fn_word_increment,attrib_1),%b%r[setq(3,extract(v(attrib_1),#@,1))][setq(9,[ansi(v(head_color),%q3:)][space(sub(12,strlen(%q3)))][ifelse(hasattr(%q0,%q3),u(%q0/%q3),Not set.)])]%q9[repeat(%b,sub(40,strlen(%q9)))][setq(4,extract(v(attrib_2),#@,1))][ansi(v(head_color),%q4:)][space(sub(12,strlen(%q4)))][ifelse(hasattr(%q0,%q4),u(%q0/%q4),Not set.)])]%r[repeat(ansi([v(border_color)],-=),40)]%r[iter(v(attrib_3),%r[ansi(v(head_color),##:)][space(sub(8,strlen(##)))][ifelse(hasattr(%q0,##),u(%q0/##),Not set.)])]%r%r[repeat(ansi([v(border_color)],-=),40)]),0,pemit(%q0,[ansi(hc,capstr(%0))] is not an existing [mudname()] player.))]; @verb %q0=%#,,,,,AFINGER
&HEAD_COLOR +finger Device=hr
&BORDER_COLOR +finger Device=hb
&FMT-SPACE_DIGIT +finger Device=[switch(lte(v(0),9),1,0)][v(0)]
&FMT-TWO_DIGIT +finger Device=[switch(lte(v(0),9),1,0)][v(0)]
@Comment +finger Device=The online time format code has been borrowed from Kynn Bartlett's old "3who" command.
&FN_TIME_FORMAT +finger Device=[setq(9,div(conn(%0),86400))][ifelse(gt(%q9,0),%q9 days%b,)][u(fmt-space_digit,div([ifelse(gt(%q9,0),mod(conn(%0),86400),conn(%0))],3600))] hours and [u(fmt-two_digit,div(mod(conn(%0),3600),60))] minutes.
&SHOWFLAGS +finger Device=1
&ATTRIB_1 +finger Device=Age Species AIM Birthday
&ATTRIB_2 +finger Device=Sex Status ICQ Hometown
&FN_WORD_INCREMENT +finger Device=iter(lnum(words(u(%0))),add(##,1))
&ATTRIB_3 +finger Device=Notes WWW Quote Email
&PBACKGROUND +finger Device=$+background *:@switch hastype(*%0,player)=1,{@pemit %#=[ansi(v(border_color),repeat(-=,40))]%r[center(ansi(v(head_color),Background for [name(*%0)][ifelse(v(showflags), \([num(*%0)][flags(*%0)]\),)]),80)]%r[ansi(v(border_color),repeat(-=,40))]%r[ifelse(hasattr(*%0/back_ok),u(*%0/background),This player has chose not to make [poss(*%0)] background public.)]%r[ansi(v(border_color),repeat(-=,40))]},{@pemit %#=[ansi(hb,%0 is not a valid [mudname()] player.)]}
&PLOOK +finger Device=$+look *:@switch hastype(*%0,player)=1,{@pemit %#=[ansi(v(border_color),repeat(-=,40))]%r[center(ansi(v(head_color),[name(*%0)][ifelse(v(showflags), \([num(*%0)][flags(*%0)]\),)]),80)]%r[ansi(v(border_color),repeat(-=,40))]%r[ansi(v(head_color),Alias:)][u(*%0/alias)]%t[ansi(v(head_color),Sex:)][u(*%0/sex)]%r[ansi(v(border_color),repeat(-=,40))]%r[u(*%0/desc)]%r[ansi(v(border_color),repeat(-=,40))]},{@pemit %#=[ansi(hb,%0 is not a valid [mudname()] player.)]}
@set +finger Device=INHERIT
@set +finger Device=SAFE

@create +where Device=10
@lock +where Device=*Yohshee
&PWHERE +where Device=$+where:think [pemit(%#,[ansi(v(bar_color),+[repeat(-=,5)])][repeat(%b,2)][ansi(v(head_color),+where)][repeat(%b,2)][ansi(v(bar_color),[repeat(-=,5)]+)])][pemit(%#,[list(lwho(),[u(fn_where,##)])])][pemit(%#,[ansi(v(bar_color),+[repeat(-=,5)])]%b[ansi(v(head_color),[words(lwho())]%bplayers.)]%b[ansi(v(bar_color),[repeat(-=,5)]+)])]
&FN_WHERE +where Device=[ansi(v(player_color),name(%0))][repeat(.,sub(13,[strlen(name(%0))]))]%b[ifelse(hasflag(%0,unfindable),ansi(h,Unfindable.),ifelse(hasflag(loc(%0),unfindable),ansi(h,------),name(loc(%0))))]
&AUTHOR +where Device=Yohshee
&VERSION +where Device=1.0
@Desc +where Device=You see before you a little blue, steel box with steel screws holding it together. A few small, colored wires lead out from it. Looking at the wires, you see that they hook into various outlets on the MUX, like the who. Interesting.%rThe command is +where! It produces a nice listing of where everyone is. Kind of a condensed +who, in a sense.%rIn order to change the colors, merely set the following attributes to any of the tokens accepted by the ansi() function:%r%t%tbar_color - The bars at the top and bottom%r%t%thead_color - The header color.%r%t%tplayer_color - The color of the players in the listing.%r(Coded by Yohshee@Toast)
&BAR_COLOR +where Device=c
&HEAD_COLOR +where Device=hy
&PLAYER_COLOR +where Device=h
&PWHERE-SINGLE +where Device=$+where *:@switch hastype(*%0,player)=1,{@switch hasflag(*%0,connected)=1,{@pemit %#=[ansi(v(player_color),+where)]%b[ansi(v(head_color),-->)] [ansi(v(player_color),name(*%0))] is currently [ifelse(hasflag(*%0,unfindable),unfindable,located at [name(loc(*%0))])].},{@pemit %#=That player isn't connected.}},{@pemit %#=That isn't an existing [mudname()] player.}
@set +where Device=INHERIT
@set +where Device=SAFE

@create OOC Device=10
@lock OOC Device=*Yohshee
&CMD-OOC OOC Device=$ooc *:@switch mid(%0,0,1)=:,{@remit [loc(%#)]=[ansi(hg,\()][ansi(hb,OOC)][ansi(hg,\))] [name(%#)] [delete(%0,0,1)]},v(scol),{@remit [loc(%#)]=[ansi(hg,\()][ansi(hb,OOC)][ansi(hg,\))] [name(%#)][delete(%0,0,1)]},{@remit [loc(%#)]=[ansi(hg,\()][ansi(hb,OOC)][ansi(hg,\))] [name(%#)] says, "%0"}
&SCOL OOC Device=;
@set OOC Device=SAFE

@create Player Globals=10
@lock Player Globals=*Yohshee
&PSELFBOOT Player Globals=$+selfboot:@switch words(ports(%#))=1,{@pemit %#=You are only connected once.},{@va me=[words(ports(%#))]; @dolist [rest(ports(%#))]={@boot/port ##}; @pemit %#=%va connection(s) removed.}
&CMD-IC Player Globals=$+ic:@switch hasattr(%#,status)=1,{@switch strmatch(u(%#/status),IC)=1,{@remit loc(%#)=%n returns to the IC area.; @teleport/quiet %#=[u(%#/ic)]; @unlock %#/status; &status %#=IC; @lock %#/status=[owner(me)]},{@pemit %#=You are already IC. Use +ooc to return to the OOC area.}},{@pemit %#=You need to go through Chargen before you can use this command.}
&CMD-OOC Player Globals=$+ooc:@switch hasattr(%#,status)=1,{@switch strmatch(u(%#/status),OOC)=1,{@remit loc(%#)=%n goes to the OOC area.; @unlock %#/ic; &ic %#=[loc(%#)]; @lock %#/ic=[owner(me)]; @teleport/quiet %#=[u(oocarea)]; @unlock %#/status; &status %#=OOC; @lock %#/status=[owner(me)]},{@pemit %#=You are already OOC. Use +ic to return to the IC area.}},{@pemit %#=You need to go through Chargen before you can use this command.}
&OOCAREA Player Globals=<insert dbref of ooc area>
@set Player Globals=INHERIT
@set Player Globals=SAFE